Datum i Excel
Här går vi igenom de vanligaste funktionerna och vanliga beräkningar med exempel för att hantera datum i Microsoft Excel.
Datumhantering i Excel är en viktig färdighet för alla som arbetar med dataanalys, rapportering eller någon form av tidsbaserad information. Excel erbjuder ett brett spektrum av funktioner och verktyg för att hantera datum, vilket kan hjälpa dig att utföra allt från enkla beräkningar till komplexa analyser.
Grunder
Datumsystem
I Excel representeras datum som serienummer där 1 motsvarar 1 januari 1900. Detta gör att du kan utföra matematiska operationer direkt på datum. I äldre versioner av Excel användes ett system som utgick från 1904, men detta bör undvikas för att slippa framtida problem.
Komma eller semikolon?
I många europeiska länder, inklusive Sverige, används komma som decimaltecken, medan i engelsktalande länder används punkt som decimaltecken. För att undvika förvirring används därför semikolon för att separera argument i svenska Excel och komma i engelska Excel. Genom att vara medveten om dessa skillnader kan man undvika misstag när man arbetar med Excel-dokument som är skapade med olika språkversioner.
// Svenska Excel
=SUMMA(A1; A2; A3)
// Engelska Excel
=SUM(A1, A2, A3)
Nedan anges samtliga funktioner med semikolon, vilket är vanligast i svenska installationer av Excel.
Allmänna funktioner
DATUM (DATE)
Funktionen DATUM(år; månad; dag) skapar ett datum från enskilda år-, månads- och dagsvärden. Användbar när du bygger ett datum från delar.
=DATUM(2024; 7; 23)
Aktuellt datum
IDAG (TODAY)
Funktionen IDAG() returnerar dagens datum. Används när du behöver dagens datum dynamiskt.
=IDAG()
NU (NOW)
Funktionen NU() returnerar både dagens datum och aktuellt klockslag. Används för tidsstämplar.
=NU()
Formatera och konvertera datum
Formatera datum med TEXT
Funktionen TEXT(värde; format) formaterar ett datum till en sträng enligt angivet format.
// A1 = 2024-07-01
=TEXT(A1; "ÅÅÅÅ-MM-DD") // => 2024-07-01
=TEXT(A1; "D MMMM ÅÅÅÅ") // => 1 juli 2027
Skapa datum från text med DATUMVÄRDE (DATEVALUE)
Funktionen DATUMVÄRDE(datumtext) konverterar ett datum som lagras som text till ett serienummer som kan identifieras som ett datum i Excel.
=DATUMVÄRDE("2024-07-01") => // 2024-07-01
Datuminformation
DAG (DAY), MÅNAD (MONTH), ÅR (YEAR)
Dessa funktioner extraherar dagen, månaden respektive året från ett datum. Användbara för att dela upp datum i komponenter.
// A1 = 2024-07-01
=DAG(A1) // => 1
=MÅNAD(A1) // => 7
=ÅR(A1) // => 2024
VECKODAG (WEEKDAY)
Funktionen VECKODAG(datum; [returtyp]) returnerar vilken veckodag ett datum infaller på, där returtyp bestämmer formatet på resultatet. Returtyp “2” returnerar svar utifrån den svenska kalendern där 1 är måndag och 7 är söndag.
// A1 = 2024-07-01
=VECKODAG(A1; 2) // => 1
Veckonummer med VECKONR (WEEKNUM)
Funktionen VECKONR(datum; [returtyp]) returnerar veckan på året för ett datum. Returtyp “2” returnerar svar utifrån den svenska kalendern där veckan inleds med månadg.
// A1 = 2024-07-01
=VECKONUMMER(A1; 2) // => 27
Månadens sista dag med SLUTMÅNAD (EOMONTH)
Funktionen SLUTMÅNAD(startdatum, månader) beräknar sista dagen i månaden, förskjutet med angivet antal månader.
// A1 = 2024-07-01
=SLUTMÅNAD(A1; 0) // => 2027-07-31
=SLUTMÅNAD(A1; 2) // => 2027-09-30
=SLUTMÅNAD(A1; -2) // => 2027-05-31
Skillnad mellan datum
Beräkna dagar mellan två datum
Använd enkel subtraktion för att beräkna antalet dagar från ett visst datum till och med ett annat.
// A1 = 2024-07-01
// A2 = 2024-07-15
=A2-A1 // => 14
=A1-A2 // => -14
Skillnad i År, Månader och Dagar med DATEDIF
Funktionen DATEDIF(startdatum; stoppdatum; enhet) beräknar skillnaden i år, månader eller dagar från ett visst datum till och med ett annat.
=DATEDIF(A1; A2; "Y") // Skillnad i år
=DATEDIF(A1; A2; "M") // Skillnad i månader
=DATEDIF(A1; A2; "D") // Skillnad i dagar
Notera att startdatum måste vara före stoppdatum och att det därför inte går att få ett negativt värde. Vet du inte vilket datum som är störst och vill ange ett negativt värde om A2 är mindre A1 kan du använda funktionen =DATEDIF(MIN(A1; A2); MAX(A1; A2); "D") * OM(A1 < A2; 1; -1).
Lägg till eller dra ifrån
Lägga till eller dra ifrån dagar
För att lägga till eller dra ifrån ett visst antal dagar från ett datum, kan du använda enkel addition eller subtraktion.
// A1 = 2024-07-01
=A1 + 14 // => 2024-07-15
=A1 - 14 // => 2024-06-17
Lägga till eller dra ifrån månader med EDATUM (EDATE)
Funktionen EDATUM(startdatum; månader) används för att lägga till eller dra ifrån hela månader.
// A1 = 2024-07-01
=EDATUM(A1; 3) // 2024-10-01
=EDATUM(A1; -3) // 2024-04-01
Arbetsdagar och helgdagar
Nästa arbetsdag med ARBETSDAG (WORKDAY)
Funktionen ARBETSDAGAR(startdatum; arbetsdagar; [helgdagar]) returnerar ett datum som ligger ett visst antal arbetsdagar från startdatumet.
=ARBETSDAGAR(A1; 10) // Lägger till 10 arbetsdagar till datumet i A1
Inkluderar helgdagar för att lägga till dagar utöver lördagar och söndagar som inte ska räknas som arbetsdagar.
Skillnad i arbetsdagar med NETTOARBETSDAGAR (NETWORKDAYS)
Funktionen NETTOARBETSDAGAR(startdatum; slutdatum; [helgdagar]) beräknar antalet arbetsdagar från ett visst datum till och med ett annat.
=NETTOARBETSDAGAR(A1; A2)
Inkluderar helgdagar för att lägga till dagar utöver lördagar och söndagar som inte ska räknas som arbetsdagar.
Exempel
Beräkning av ålder
=DATEDIF(A1; IDAG(); "Y")